�?мпорт начальных данных в подсистему Отдел Кадров

' На вход передается строка с датой в формате дд.мм.гггг
' Сконвертированная дата помещается в переменную D
' Функция возвращает True если конвертация прошла успешно
Function I2W_Str2Date(S, ByRef D)
 I2W_Str2Date = False
 
 Dim A
 A = Split(S, ".")
 
 If UBound(A) = 2 Then
   If IsNumeric(A(0)) And IsNumeric(A(1)) And IsNumeric(A(2)) Then
     If ((A(0) >= 1) And (A(0) <= 31)) And _
        ((A(1) >= 1) And (A(1) <= 12)) And _
        ((A(2) >= 1900) And (A(2) <= 2999)) Then
       D = DateSerial(A(2), A(1), A(0))
       I2W_Str2Date = True
     End If
   End If
 End If
End Function
 
' На вход передается строка в CSV формате и символ разделитель значений.
' На выходе -- массив значений
Function I2W_Split(S, DelimChar)
 Const QuoteChar = """"
 
 ReDim Result(0)
 Dim I, B, E, CurrChar, InQuotes
 
 I = 0
 B = 1
 E = 1
 InQuotes = False
 Result(0) = ""
 
 While E <= Len(S)
   CurrChar = Mid(S, E, 1)
 
   If CurrChar = QuoteChar Then
     If Mid(S, E + 1, 1) = QuoteChar Then
       E = E + 1
     ElseIf Mid(S, E + 1, 1) = DelimChar Then
       If InQuotes Then
         CurrChar = ""
         InQuotes = False
       End If
     ElseIf E = B Then
       InQuotes = True
       CurrChar = ""
     End If
   ElseIf (CurrChar = DelimChar) And (Not InQuotes) Then
     I = I + 1
     ReDim Preserve Result(I)
     Result(I) = ""
     B = E + 1
     CurrChar = ""
   End If
 
   If CurrChar > "" Then
     Result(I) = Result(I) & CurrChar
   End If
 
   E = E + 1
 WEnd
 
 If (UBound(Result) > 0) And (Result(UBound(Result)) = "") Then
   ReDim Preserve Result(UBound(Result) - 1)
 End If
 
 I2W_Split = Result
End Function